默认分类 Fortran

Fortran Associate结构学习

MetMan博主神仙

2025-03-22

0 评论

67 阅读

281 个字

百度已收录

03/22

本文最后更新于 2025年03月22日，已超过 34天没有更新。如果文章内容或图片资源失效，请留言反馈，我会及时处理，谢谢！

只要代码写得多，总能Get新知识。

Fortran 2003标准中associate结构应该不常用，但associate结构用好可以简化复杂语句，增加代码的可读性。

可以将associate关联名字看成是要指向的表达式或者变量的别名（引用），供后续代码使用。

语法

[name:] ASSOCIATE (assoc-entity[, assoc-entity]...)

   block

END ASSOCIATE [name]

其中name是可选的，associate结构名称，如果指定，后面的end assoicate也必须加上相同的名称。

assoc-entity语法为assoicate-name => selector，其中selector是一个表达式或者变量，而associate-name是关联selector的别名。

block是零条或者多条Fortran语句/结构。

示例：

program associateTest

  implicit none
  integer :: a=1,b=1
  associate( x => a*b )       ! 表达式的引用
    print *, x                ! yields: 1
    a=10
    print *, x                ! yields: 1
  end associate

  associate( x => a )         ! 变量的引用 
    print *, x                ! yields: 10
    a=100
    print *, x                ! yields: 100
  end associate

end program associateTest

注意表达式和变量assoicate引用的区别。

用途

assoicate主要用途：增加代码可读性。性能方面，可能会一定程度上帮助编译器优化。

This said, I have experience that "increasing code reading clarity" also enabled the compiler to generate more optimal code. This is not that the associated reference is inherently more optimal, but rather it reduces the complexity to the compiler optimization with respect to tracking common sub-expressions and their elimination/reduction. 引自Fortran专家

对于复杂的派生类型，associate可以起到简化代码作用：

ASSOCIATE (ARRAY => AB % D (I, :) % X)
  ARRAY (3) = ARRAY (1) + ARRAY (2)
END ASSOCIATE

ARRAY是变量AB % D (I, :) % X的引用，因此ARRAY(3)相当于AB % D (I, 3) % X。

上面代码等价于

AB % D (I, 3) % X = AB % D (I, 1) % X + AB % D (I, 2) % X

对比一下，确实是associate结构代码清晰。

对于变量，也可以使用POINTER直接指向变量进行引用。

program main
  implicit none
  type t1
    integer :: x
  end type t1

  type t2
    type(t1) :: D(10,10)
  end type t2

  type(t2),target :: AB

  integer :: i
  integer,pointer :: ptr(:)

  do i=1,10
    associate(array => AB%D(I,:)%X)  ! assoicate结构
      array(:) = i
      array(3) = array(1) + array(2)
      print*,array(3)
    end associate
  enddo

  do i=1,10
    ptr => AB%D(i,:)%X  ! 指针指向变量
    ptr(3) = ptr(1) + ptr(2)
    print*,ptr(3)
    nullify(ptr)
  enddo
end