默认分类 Fortran

Fortran数组转置

MetMan博主神仙

2025-03-22

0 评论

29 阅读

368 个字

百度已收录

03/22

本文最后更新于 2025年03月22日，已超过 13天没有更新。如果文章内容或图片资源失效，请留言反馈，我会及时处理，谢谢！

数组转置（transpose）是一个常见的操作。

二维数组转置

Fortran标准有一个内置函数transpose可以对Rank-2数组进行转置操作。

program main
  implicit none
  integer :: a(3,4) = reshape([1,2,3,4,5,6,7,8,9,10,11,12], [3,4])
  integer,allocatable :: b(:,:)

  b = transpose(a)
  print*, 'shape(b) = ', shape(b)
  print*, 'b = ', b
end program

更高维数组转置

但对于高维数组，如何转置？

显式循环

使用显式嵌套循环进行数组转置，下面使用do concurrent结构对一个4维数组转职。

dims = shape(x) 
allocate(res(dims(4), dims(3), dims(2), dims(1))) 
do concurrent(i = 1:dims(1), j = 1:dims(2), k = 1:dims(3), l = 1:dims(4)) 
  res(l,k,j,i) = x(i,j,k,l) 
end do

使用do concurrent结构可以让编译器进行优化，该结构表明循环迭代之间没有依赖性，编译器可以对其多线程及向量优化。

高级用法

以下代码段是从Fortran论坛看到的，可以自动适配不同rank数组的转置。

integer,allocatable :: array(:,:,:,:)
allocate(array(5,6,2,4))

associate(shape => shape(array)) 
  array = reshape(array, shape=shape(rank(array):1:-1), order=[(i, i=rank(array), 1, -1)])
end associate

这里涉及到的Fortran语法点包括：

shape内置函数返回一个一维数组，描述数组的形状
reshape内置函数通过order参数进行数组维变化，进而实现转置操作[[Fortran Array Constructor]]
可分配数组自动Left-Hand-Side重新分配，即赋值语句右端表达式返回的数组形状与左端可分配数组变量不同时，左端数组会reallocate右端相同shape的数组
Fortran 2018 rank内置函数，返回变量对象的rank
associate结构介绍见[[Fortran associate结构学习]]

上面代码可以解释为：首先shape内置函数返回一个rank-1数组，使用assoicate结构关联shape指向shape(array)后，shape就是一个rank-1数组[5,6,2,4]，然后shape(rank(array):1:-1)解释将数组倒序，变为[4,2,6,5]，这就是新数组的形状。通过order=[4,3,2,1]对原数组进行转置。

! 一维数组倒排语法
a(1:4)=[5,6,2,4] 
print*, a(4:1:-1)  ! [4,2,6,5]

示例：

program multi_array_transpose
  implicit none
  integer,allocatable :: a(:,:,:,:)
  integer :: i

  allocate(a(5,6,2,4))
  a = reshape([(i,i=1,5*6*2*4)],shape(a))

  print*,'original shape(a)',shape(a)
  print*,a(5,6,2,4)
  associate(shape=>shape(a))
    a = reshape(a,shape=shape(rank(a):1:-1),order=[(i,i=rank(a),1,-1)])
  end associate
  print*,'after reshape, shape(a)',shape(a)
  print*,a(4,2,6,5)
end